home *** CD-ROM | disk | FTP | other *** search
/ SGI Developer Toolbox 6.1 / SGI Developer Toolbox 6.1 - Disc 4.iso / lib / mathlib / libblas / src_original / zherk.f < prev    next >
Encoding:
Text File  |  1994-08-02  |  10.5 KB  |  325 lines
  1. *
  2. ************************************************************************
  3. *
  4.       SUBROUTINE ZHERK ( UPLO, TRANS, N, K, ALPHA, A, LDA,
  5.      $                   BETA, C, LDC )
  6. *     .. Scalar Arguments ..
  7.       CHARACTER*1        UPLO, TRANS
  8.       INTEGER            N, K, LDA, LDC
  9.       DOUBLE PRECISION   ALPHA, BETA
  10. *     .. Array Arguments ..
  11.       COMPLEX*16         A( LDA, * ), C( LDC, * )
  12. *     ..
  13. *
  14. *  Purpose
  15. *  =======
  16. *
  17. *  ZHERK  performs one of the hermitian rank k operations
  18. *
  19. *     C := alpha*A*conjg( A' ) + beta*C,
  20. *
  21. *  or
  22. *
  23. *     C := alpha*conjg( A' )*A + beta*C,
  24. *
  25. *  where  alpha and beta  are  real scalars,  C is an  n by n  hermitian
  26. *  matrix and  A  is an  n by k  matrix in the  first case and a  k by n
  27. *  matrix in the second case.
  28. *
  29. *  Parameters
  30. *  ==========
  31. *
  32. *  UPLO   - CHARACTER*1.
  33. *           On  entry,   UPLO  specifies  whether  the  upper  or  lower
  34. *           triangular  part  of the  array  C  is to be  referenced  as
  35. *           follows:
  36. *
  37. *              UPLO = 'U' or 'u'   Only the  upper triangular part of  C
  38. *                                  is to be referenced.
  39. *
  40. *              UPLO = 'L' or 'l'   Only the  lower triangular part of  C
  41. *                                  is to be referenced.
  42. *
  43. *           Unchanged on exit.
  44. *
  45. *  TRANS  - CHARACTER*1.
  46. *           On entry,  TRANS  specifies the operation to be performed as
  47. *           follows:
  48. *
  49. *              TRANS = 'N' or 'n'   C := alpha*A*conjg( A' ) + beta*C.
  50. *
  51. *              TRANS = 'C' or 'c'   C := alpha*conjg( A' )*A + beta*C.
  52. *
  53. *           Unchanged on exit.
  54. *
  55. *  N      - INTEGER.
  56. *           On entry,  N specifies the order of the matrix C.  N must be
  57. *           at least zero.
  58. *           Unchanged on exit.
  59. *
  60. *  K      - INTEGER.
  61. *           On entry with  TRANS = 'N' or 'n',  K  specifies  the number
  62. *           of  columns   of  the   matrix   A,   and  on   entry   with
  63. *           TRANS = 'C' or 'c',  K  specifies  the number of rows of the
  64. *           matrix A.  K must be at least zero.
  65. *           Unchanged on exit.
  66. *
  67. *  ALPHA  - DOUBLE PRECISION.
  68. *           On entry, ALPHA specifies the scalar alpha.
  69. *           Unchanged on exit.
  70. *
  71. *  A      - COMPLEX*16       array of DIMENSION ( LDA, ka ), where ka is
  72. *           k  when  TRANS = 'N' or 'n',  and is  n  otherwise.
  73. *           Before entry with  TRANS = 'N' or 'n',  the  leading  n by k
  74. *           part of the array  A  must contain the matrix  A,  otherwise
  75. *           the leading  k by n  part of the array  A  must contain  the
  76. *           matrix A.
  77. *           Unchanged on exit.
  78. *
  79. *  LDA    - INTEGER.
  80. *           On entry, LDA specifies the first dimension of A as declared
  81. *           in  the  calling  (sub)  program.   When  TRANS = 'N' or 'n'
  82. *           then  LDA must be at least  max( 1, n ), otherwise  LDA must
  83. *           be at least  max( 1, k ).
  84. *           Unchanged on exit.
  85. *
  86. *  BETA   - DOUBLE PRECISION.
  87. *           On entry, BETA specifies the scalar beta.
  88. *           Unchanged on exit.
  89. *
  90. *  C      - COMPLEX*16       array of DIMENSION ( LDC, n ).
  91. *           Before entry  with  UPLO = 'U' or 'u',  the leading  n by n
  92. *           upper triangular part of the array C must contain the upper
  93. *           triangular part  of the  hermitian matrix  and the strictly
  94. *           lower triangular part of C is not referenced.  On exit, the
  95. *           upper triangular part of the array  C is overwritten by the
  96. *           upper triangular part of the updated matrix.
  97. *           Before entry  with  UPLO = 'L' or 'l',  the leading  n by n
  98. *           lower triangular part of the array C must contain the lower
  99. *           triangular part  of the  hermitian matrix  and the strictly
  100. *           upper triangular part of C is not referenced.  On exit, the
  101. *           lower triangular part of the array  C is overwritten by the
  102. *           lower triangular part of the updated matrix.
  103. *           Note that the imaginary parts of the diagonal elements need
  104. *           not be set,  they are assumed to be zero,  and on exit they
  105. *           are set to zero.
  106. *
  107. *  LDC    - INTEGER.
  108. *           On entry, LDC specifies the first dimension of C as declared
  109. *           in  the  calling  (sub)  program.   LDC  must  be  at  least
  110. *           max( 1, n ).
  111. *           Unchanged on exit.
  112. *
  113. *
  114. *  Level 3 Blas routine.
  115. *
  116. *  -- Written on 8-February-1989.
  117. *     Jack Dongarra, Argonne National Laboratory.
  118. *     Iain Duff, AERE Harwell.
  119. *     Jeremy Du Croz, Numerical Algorithms Group Ltd.
  120. *     Sven Hammarling, Numerical Algorithms Group Ltd.
  121. *
  122. *
  123. *     .. External Functions ..
  124.       LOGICAL            LSAME
  125.       EXTERNAL           LSAME
  126. *     .. External Subroutines ..
  127.       EXTERNAL           XERBLA
  128. *     .. Intrinsic Functions ..
  129.       INTRINSIC          DCMPLX, DCONJG, MAX, DBLE
  130. *     .. Local Scalars ..
  131.       LOGICAL            UPPER
  132.       INTEGER            I, INFO, J, L, NROWA
  133.       DOUBLE PRECISION   RTEMP
  134.       COMPLEX*16         TEMP
  135. *     .. Parameters ..
  136.       DOUBLE PRECISION   ONE ,         ZERO
  137.       PARAMETER        ( ONE = 1.0D+0, ZERO = 0.0D+0 )
  138. *     ..
  139. *     .. Executable Statements ..
  140. *
  141. *     Test the input parameters.
  142. *
  143.       IF( LSAME( TRANS, 'N' ) )THEN
  144.          NROWA = N
  145.       ELSE
  146.          NROWA = K
  147.       END IF
  148.       UPPER = LSAME( UPLO, 'U' )
  149. *
  150.       INFO = 0
  151.       IF(      ( .NOT.UPPER               ).AND.
  152.      $         ( .NOT.LSAME( UPLO , 'L' ) )      )THEN
  153.          INFO = 1
  154.       ELSE IF( ( .NOT.LSAME( TRANS, 'N' ) ).AND.
  155.      $         ( .NOT.LSAME( TRANS, 'C' ) )      )THEN
  156.          INFO = 2
  157.       ELSE IF( N  .LT.0               )THEN
  158.          INFO = 3
  159.       ELSE IF( K  .LT.0               )THEN
  160.          INFO = 4
  161.       ELSE IF( LDA.LT.MAX( 1, NROWA ) )THEN
  162.          INFO = 7
  163.       ELSE IF( LDC.LT.MAX( 1, N     ) )THEN
  164.          INFO = 10
  165.       END IF
  166.       IF( INFO.NE.0 )THEN
  167.          CALL XERBLA( 'ZHERK ', INFO )
  168.          RETURN
  169.       END IF
  170. *
  171. *     Quick return if possible.
  172. *
  173.       IF( ( N.EQ.0 ).OR.
  174.      $    ( ( ( ALPHA.EQ.ZERO ).OR.( K.EQ.0 ) ).AND.( BETA.EQ.ONE ) ) )
  175.      $   RETURN
  176. *
  177. *     And when  alpha.eq.zero.
  178. *
  179.       IF( ALPHA.EQ.ZERO )THEN
  180.          IF( UPPER )THEN
  181.             IF( BETA.EQ.ZERO )THEN
  182.                DO 20, J = 1, N
  183.                   DO 10, I = 1, J
  184.                      C( I, J ) = ZERO
  185.    10             CONTINUE
  186.    20          CONTINUE
  187.             ELSE
  188.                DO 40, J = 1, N
  189.                   DO 30, I = 1, J - 1
  190.                      C( I, J ) = BETA*C( I, J )
  191.    30             CONTINUE
  192.                   C( J, J ) = BETA*DBLE( C( J, J ) )
  193.    40          CONTINUE
  194.             END IF
  195.          ELSE
  196.             IF( BETA.EQ.ZERO )THEN
  197.                DO 60, J = 1, N
  198.                   DO 50, I = J, N
  199.                      C( I, J ) = ZERO
  200.    50             CONTINUE
  201.    60          CONTINUE
  202.             ELSE
  203.                DO 80, J = 1, N
  204.                   C( J, J ) = BETA*DBLE( C( J, J ) )
  205.                   DO 70, I = J + 1, N
  206.                      C( I, J ) = BETA*C( I, J )
  207.    70             CONTINUE
  208.    80          CONTINUE
  209.             END IF
  210.          END IF
  211.          RETURN
  212.       END IF
  213. *
  214. *     Start the operations.
  215. *
  216.       IF( LSAME( TRANS, 'N' ) )THEN
  217. *
  218. *        Form  C := alpha*A*conjg( A' ) + beta*C.
  219. *
  220.          IF( UPPER )THEN
  221.             DO 130, J = 1, N
  222.                IF( BETA.EQ.ZERO )THEN
  223.                   DO 90, I = 1, J
  224.                      C( I, J ) = ZERO
  225.    90             CONTINUE
  226.                ELSE IF( BETA.NE.ONE )THEN
  227.                   DO 100, I = 1, J - 1
  228.                      C( I, J ) = BETA*C( I, J )
  229.   100             CONTINUE
  230.                   C( J, J ) = BETA*DBLE( C( J, J ) )
  231.                END IF
  232.                DO 120, L = 1, K
  233.                   IF( A( J, L ).NE.DCMPLX( ZERO ) )THEN
  234.                      TEMP = ALPHA*DCONJG( A( J, L ) )
  235.                      DO 110, I = 1, J - 1
  236.                         C( I, J ) = C( I, J ) + TEMP*A( I, L )
  237.   110                CONTINUE
  238.                      C( J, J ) = DBLE( C( J, J )      ) +
  239.      $                           DBLE( TEMP*A( I, L ) )
  240.                   END IF
  241.   120          CONTINUE
  242.   130       CONTINUE
  243.          ELSE
  244.             DO 180, J = 1, N
  245.                IF( BETA.EQ.ZERO )THEN
  246.                   DO 140, I = J, N
  247.                      C( I, J ) = ZERO
  248.   140             CONTINUE
  249.                ELSE IF( BETA.NE.ONE )THEN
  250.                   C( J, J ) = BETA*DBLE( C( J, J ) )
  251.                   DO 150, I = J + 1, N
  252.                      C( I, J ) = BETA*C( I, J )
  253.   150             CONTINUE
  254.                END IF
  255.                DO 170, L = 1, K
  256.                   IF( A( J, L ).NE.DCMPLX( ZERO ) )THEN
  257.                      TEMP      = ALPHA*DCONJG( A( J, L ) )
  258.                      C( J, J ) = DBLE( C( J, J )      )    +
  259.      $                           DBLE( TEMP*A( J, L ) )
  260.                      DO 160, I = J + 1, N
  261.                         C( I, J ) = C( I, J ) + TEMP*A( I, L )
  262.   160                CONTINUE
  263.                   END IF
  264.   170          CONTINUE
  265.   180       CONTINUE
  266.          END IF
  267.       ELSE
  268. *
  269. *        Form  C := alpha*conjg( A' )*A + beta*C.
  270. *
  271.          IF( UPPER )THEN
  272.             DO 220, J = 1, N
  273.                DO 200, I = 1, J - 1
  274.                   TEMP = ZERO
  275.                   DO 190, L = 1, K
  276.                      TEMP = TEMP + DCONJG( A( L, I ) )*A( L, J )
  277.   190             CONTINUE
  278.                   IF( BETA.EQ.ZERO )THEN
  279.                      C( I, J ) = ALPHA*TEMP
  280.                   ELSE
  281.                      C( I, J ) = ALPHA*TEMP + BETA*C( I, J )
  282.                   END IF
  283.   200          CONTINUE
  284.                RTEMP = ZERO
  285.                DO 210, L = 1, K
  286.                   RTEMP = RTEMP + DCONJG( A( L, J ) )*A( L, J )
  287.   210          CONTINUE
  288.                IF( BETA.EQ.ZERO )THEN
  289.                   C( J, J ) = ALPHA*RTEMP
  290.                ELSE
  291.                   C( J, J ) = ALPHA*RTEMP + BETA*DBLE( C( J, J ) )
  292.                END IF
  293.   220       CONTINUE
  294.          ELSE
  295.             DO 260, J = 1, N
  296.                RTEMP = ZERO
  297.                DO 230, L = 1, K
  298.                   RTEMP = RTEMP + DCONJG( A( L, J ) )*A( L, J )
  299.   230          CONTINUE
  300.                IF( BETA.EQ.ZERO )THEN
  301.                   C( J, J ) = ALPHA*RTEMP
  302.                ELSE
  303.                   C( J, J ) = ALPHA*RTEMP + BETA*DBLE( C( J, J ) )
  304.                END IF
  305.                DO 250, I = J + 1, N
  306.                   TEMP = ZERO
  307.                   DO 240, L = 1, K
  308.                      TEMP = TEMP + DCONJG( A( L, I ) )*A( L, J )
  309.   240             CONTINUE
  310.                   IF( BETA.EQ.ZERO )THEN
  311.                      C( I, J ) = ALPHA*TEMP
  312.                   ELSE
  313.                      C( I, J ) = ALPHA*TEMP + BETA*C( I, J )
  314.                   END IF
  315.   250          CONTINUE
  316.   260       CONTINUE
  317.          END IF
  318.       END IF
  319. *
  320.       RETURN
  321. *
  322. *     End of ZHERK .
  323. *
  324.       END
  325.